LOGIC Apps/Logic-APPLE_II_APPS.iso/pc/LOGIC Apple II 5.25" Library - DOS Part 2/DOS031.dsk/MAGIC SQUARES AND CUBES.bas

BASIC Source File | 2012-02-16 | 3KB | 105 lines

0  LIST 25900
1  FOR X = 1 TO 2000: NEXT X
10  REM ************************
20  REM
30  REM  MAGIC SQUARES AND CUBES
40  REM
50  REM    BY STUART ANSTIS
60  REM
70  REM        1979
80  REM
90  REM ************************
92  PRINT "DO YOU WANT A 2-D MAGIC SQUARE OR A 3-D MAGIC CUBE?"
94  INPUT "TYPE 2 FOR A SQUARE, 3 FOR A CUBE.....";D$
95 D =  VAL(D$)
96  IF D < >2  AND D < >3  THEN  GOTO 94
98  IF D >2  THEN  GOTO 116
100  PRINT "WHAT SIZE MAGIC SQUARE? ";
110  INPUT "TYPE A PRIME NUMBER GREATER THAN 3.....";N
112  IF 2 *(N/2 - INT(N/2)) <0.1  THEN  GOTO 110
114  GOTO 125
116  PRINT "WHAT SIZE MAGIC CUBE? ";
118  INPUT "TYPE A PRIME NUMBER EQUAL TO OR GREATER THAN 11.....";N
120  IF 2 *(N/2 - INT(N/2)) <0.1  THEN  GOTO 118
125 J = 0
128  PRINT : PRINT : PRINT
130  DIM V(N)
140  DIM S(N,N),T(N,N),U(N,N)
150  DIM ROW(N),COL(N)
155  DIM J(N,N)
160  REM  *************************
170  REM
180  REM       FIRST ROW
190  REM  INSERT DIGITS FROM 1 TO
200  REM   N IN RANDOM ORDER
210  REM
220  REM  *************************
300  FOR C = 1 TO N
310 V(C) =  INT(N * RND(1))
320  FOR K = 1 TO C -1
330  IF V(C) = V(C -K)  THEN  GOTO 310
340  NEXT K
350 U(1,C) = V(C)
360  NEXT C
400  REM  ********************
410  REM    SHIFT DIGITS 2 PLACES
420  REM  TO RIGHT IN SUCCESSIVE
430  REM         ROWS
440  REM     L=(C-2) MOD N
450  REM  ********************
500  FOR R = 2 TO N
510  FOR C = 1 TO N
520 L = N *((C -3)/N - INT((C -3)/N)) +1
530 U(R,C) = U(R -1,L)
540  NEXT C
550  NEXT R
600  REM  ********************
610  REM  SHIFT DIGITS 4 PLACES
620  REM  TO RIGHT IN SUCCESSIVE
630  REM       PLANES
635  REM  J=(C-4*P) MOD N
640  REM  ********************
700  FOR P = 1 TO N ^(D -2)
710  FOR R = 1 TO N
720  FOR C = 1 TO N
730 J = N *((C -4 *P)/N - INT((C -4 *P)/N)) +1
732 J =  INT(J +0.5)
740 S(R,C) =  INT(U(R,J))
745  NEXT C: NEXT R
750  REM  ********************
760  REM  U(R,C) FLIPPED LEFT/RIGHT
770  REM  AND UP/DOWN;
780  REM  T(R,C)=N*(L/R MIRROR IMAGE) +
790  REM        N*N*(U/D MIRROR IMAGE)
795  REM  ********************
797  FOR R = 1 TO N: FOR C = 1 TO N
800 T(R,C) = S(R,C) +N *S(R,N -C +1) +N *N *S(N -R +1,C) *(D -2)
810 SS =  INT(T(R,C)) +1
820 ROW(R) = ROW(R) +SS
830 COL(C) = COL(C) +SS
840  REM  FORMATTING STATEMENT *****
850 T = 5 - LOG(SS +1)/ LOG(10)
855  REM :PRINT THE MAGIC SQUARE *****
860  PRINT  SPC( T);SS;
865 T(R,C) = 0
866 SS = 0
870  NEXT C
880  REM  PRINT SUMS OF ROWS *****
900  PRINT "  ***  ";ROW(R)
910 ROW(R) = 0
920  PRINT
930  NEXT R
1000  REM : PRINT SUMS OF COLUMNS *****
1010  FOR C = 1 TO N
1020  PRINT "*****";
1030  NEXT C
1040  PRINT
1050  FOR C = 1 TO N
1060 T = 5 - LOG(COL(C))/ LOG(10)
1070  PRINT  SPC( T);COL(C);
1080  NEXT C
1090  FOR C = 1 TO N:COL(C) = 0: NEXT C
1100  PRINT : PRINT : PRINT
1200  NEXT P
2000  END
25900  REM <CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H>           <CTRL-J><CTRL-J><CTRL-J><CTRL-J><CTRL-J><CTRL-J><CTRL-J><CTRL-J><CTRL-J><CTRL-J><CTRL-J><CTRL-J><CTRL-J><CTRL-J><CTRL-J><CTRL-J><CTRL-J><CTRL-J><CTRL-J><CTRL-J><CTRL-J><CTRL-J><CTRL-J><CTRL-J><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H>FROM:  APPLE-CAN<CTRL-J><CTRL-J><CTRL-J><CTRL-J><CTRL-J><CTRL-J><CTRL-J><CTRL-J><CTRL-J><CTRL-J>